%{
#include <stdio.h>
#include <stdlib.h>
#include <string.h>

int lineno = 1, sentno = 0, parno = 0;
%}

%x INPARAGRAPH
%x INSENTENCE

whitespace	[ \t]+
optwhitespace	[ \t]*
emptyline	^{optwhitespace}\n
sentdelim	[.?!]
sentbegcont	[^ \t\n][^.?!\n]+$
sentend		[^ \t\n][^.?!\n]*{sentdelim}

%%

<INITIAL>{emptyline}       { ++lineno; }
<INPARAGRAPH>{emptyline}   {
      ++lineno;
      BEGIN INITIAL;
   }
<INSENTENCE>{emptyline}   {
      printf("\t*** Paragraph ended before sentence finishes\n");
      ++lineno;
      BEGIN INITIAL;
   }
<*>\n                     { ++lineno; }
<INITIAL>{optwhitespace}/[^ \t\n]     {
      ++parno;
      BEGIN INPARAGRAPH;
      printf("\n+++ Paragraph %d begins at line %d\n", parno, lineno);
   }
<INPARAGRAPH,INSENTENCE>{optwhitespace} { }
<INPARAGRAPH>{sentbegcont}       {
      ++sentno;
      printf("\tSentence %d at line %d: %s >>\n", sentno, lineno, yytext);
      BEGIN INSENTENCE;
   }
<INSENTENCE>{sentbegcont}        {
      printf("\t\t>> %s >>\n", yytext);
   }
<INPARAGRAPH>{sentend}/[ \t\n]+  {
      ++sentno;
      printf("\tSentence %d at line %d: %s\n", sentno, lineno, yytext);
   }
<INSENTENCE>{sentend}/[ \t\n]+   {
      printf("\t\t>> %s\n", yytext);
      BEGIN INPARAGRAPH;
   }

%%

int yywrap () {
   return 1;
}

int main ( int argc, char *argv[] )
{
   if (argc > 1) yyin = (FILE *)fopen(argv[1],"r");

   yylex();

   exit(0);
}